윈도우11 제품키 확인 및 정품인증 변경 삭제

윈도우11 제품키 확인 및 정품인증 변경 삭제

기존 윈도우10 사용하면서 Windows 참가자프로그램을 통해 업그레이드 설치를 한 경우라면 윈도우10 제품키를 가지고 윈도우11 정품인증이 가능합니다. 이때 등록된 윈도우11 제품키 확인하는 방법 3가지와 함께 제품키 변경 및 삭제방법을 알아보겠습니다.

Windows 참가자 프로그램 오류 - 0x8007000d 업데이트 참고

명령프롬프트 윈도우11 제품키 확인

가장 흔한 방법으로 명령프롬프트로 윈도우 설치시 사용한 제품키를 확인합니다.

윈도우 + R 눌러 실행창에 CMD를 입력 후 확인을 눌러줍니다.

윈도우11 제품키 확인 명령어

작은 MS DOS 검은색 창이 실행되면 아래 명령어를 입력합니다.

wmic path softwarelicensingservice get oa3xoriginalproductkey

그럼 윈도우11 제품키 확인할 수 있으며 제품키 변경 및 삭제를 원한다면 레지스트리편집기를 사용합니다.

레지스트리편집기 윈도우11 제품키 변경 및 삭제

윈도우11 제품키 확인하고 변경하거나 삭제하고 싶은 경우 레지스트리 편집기를 실행합니다.

윈도우키 + R 실행창에 REGEDIT 입력 후 확인을 눌러줍니다.

레지스트리 편집기가 실행되면 아래 경로로 이동합니다.

컴퓨터\HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion\SoftwareProtectionPlatform

BackupProductKeyDefault의 데이터를 확인하면 윈도우 설치시 사용한 제품키를 확인할 수 있습니다.

윈도우11 설치 제품키 변경 및 삭제

마우스 우클릭 후 수정을 통해 값 데이터를 수정하거나 삭제하느것으로 윈도우 제품키 변경 및 삭제가 가능합니다.

윈도우11 제품키 확인 스크립트

메모장 "Notepad"를 실행 후 아래 스크립트를 메모장에 붙여넣기 해줍니다.

Option Explicit  
 
Dim objshell,path,DigitalID, Result  
Set objshell = CreateObject("WScript.Shell") 
'Set registry key path 
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\" 
'Registry key value 
DigitalID = objshell.RegRead(Path & "DigitalProductId") 
Dim ProductName,ProductID,ProductKey,ProductData 
'Get ProductName, ProductID, ProductKey 
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName") 
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID") 
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)  
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey 
'Show messbox if save to a file  
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then 
   Save ProductData  
End If 
 
 
 
'Convert binary to chars 
Function ConvertToKey(Key) 
    Const KeyOffset = 52 
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert 
    'Check if OS is Windows 8 
    isWin8 = (Key(66) \ 6) And 1 
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4) 
    i = 24 
    Maps = "BCDFGHJKMPQRTVWXY2346789" 
    Do 
           Current= 0 
        j = 14 
        Do 
           Current = Current* 256 
           Current = Key(j + KeyOffset) + Current 
           Key(j + KeyOffset) = (Current \ 24) 
           Current=Current Mod 24 
            j = j -1 
        Loop While j >= 0 
        i = i -1 
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput 
        Last = Current 
    Loop While i >= 0  
     
    If (isWin8 = 1) Then 
        keypart1 = Mid(KeyOutput, 2, Last) 
        insert = "N" 
        KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0) 
        If Last = 0 Then KeyOutput = insert & KeyOutput 
    End If     
     
 
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5) 
    
     
End Function 
'Save data to a file 
Function Save(Data) 
    Dim fso, fName, txt,objshell,UserName 
    Set objshell = CreateObject("wscript.shell") 
    'Get current user name  
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")  
    'Create a text file on desktop  
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt" 
    Set fso = CreateObject("Scripting.FileSystemObject") 
    Set txt = fso.CreateTextFile(fName) 
    txt.Writeline Data 
    txt.Close 
End Function

이후 메모장을 다른이름으로 저장을 눌러 줍니다.

저장 시 파일형식 -> 모든파일 변경 후 저장이름을 "BackupWindowsKey.vbs" 설정합니다.

윈도우11 제품키 및 설치키 확인

저장된 "BackupWindowsKey.vbs" 파일을 실행하면 Windows Product ID 및 Installed Key로 윈도우11 제품ID 및 설치키를 확인할 수 있습니다.

BackupWindowsKey.vbs

0.00MB

해당파일을 만드는게 어렵다며 위 파일을 다운로드 받아 실행해도 됩니다.

윈도우11 정품인증 제품키 등록 4가지 방법

 

윈도우11 제품키 변경 및 라이센스 프로 업그레이드